Rápido POPUP tipo tabla (formato ALV)

FORM f_popup_tabla TABLES param_tabla.

  DATA: it_tabla     TYPE TABLE OF zpopup_tipotabla.

  DATA: gr_table     TYPE REF TO cl_salv_table.
  DATA: gr_functions TYPE REF TO cl_salv_functions.
  DATA: gr_display   TYPE REF TO cl_salv_display_settings.
  DATA: gr_columns   TYPE REF TO cl_salv_columns_table.
  DATA: gr_column    TYPE REF TO cl_salv_column_table.
  DATA: gr_layout    TYPE REF TO cl_salv_layout.
  DATA: gr_select    TYPE REF TO cl_salv_selections.
  DATA: key          TYPE salv_s_layout_key.
  DATA: it_row       TYPE salv_t_row.

  CLEAR: it_row, it_tabla.
  REFRESH: it_row, it_tabla.

  it_tabla[] = param_tabla[].

* FACTORY permite crear un objeto ALV. Instancia GR_TABLE para tabla ALV
  cl_salv_table=>factory( IMPORTING r_salv_table = gr_table
                          CHANGING  t_table      = it_tabla ).

* Obtenemos los parámetros de visualización
  gr_display = gr_table->get_display_settings( ).
* ALV Grid filas
  gr_display->set_striped_pattern( cl_salv_display_settings=>true ).
* Título
  gr_display->set_list_header( 'TÍTULO DEL POP-UP' ).

* Cambiamos los descriptivos de las columnas
  gr_columns = gr_table->get_columns( ).
  gr_column ?= gr_columns->get_column( 'COLUMNA' ).
  gr_column->set_long_text( 'Nombre Columna' ).

* Selección tipo
  gr_select = gr_table->get_selections( ).
  gr_select->set_selection_mode( if_salv_c_selection_mode=>single ).

* Mostrar a modo de ventana emergente
  gr_table->set_screen_popup(
    EXPORTING
      start_column = 10
      end_column   = 80
      start_line   = 10
      end_line     = 17
  ).

* Display ALV Grid
  gr_table->display( ).

ENDFORM.                    " F_POPUP_DUPLICADAS